Комментарии

@echo off
setlocal

cd /d "%~dp0"

net session >nul 2>&1
if %errorlevel% neq 0 (
powershell -Command "Start-Process -FilePath '%~f0' -WorkingDirectory '%~dp0' -Verb RunAs"
exit /b
)

set DRIVERFILE=Randgrid.sys
set DRIVERNAME=atvi-randgrid_sr_offline
set EXENAME=sp26-cod.exe
set EMUCFG=%CD%\sp26\steam_settings\configs.main.ini

findstr /i /c:"offline=0" "%EMUCFG%" >nul && findstr /i /c:"disable_lan_only=1" "%EMUCFG%" >nul || (> "%EMUCFG%" echo [main::connectivity]& >> "%EMUCFG%" echo offline=0& >> "%EMUCFG%" echo disable_lan_only=1)
dir /al "%CD%\sp26" 2>nul | findstr /i /c:"xpak_cache" >nul || mklink /J "%CD%\sp26\xpak_cache" "%CD%\xpak_cache" >nul || echo WARNING: sp26\xpak_cache exists but is not a junction, cached textures will not be used

sc query %DRIVERNAME% >nul 2>&1
if %errorlevel%==0 (
echo AC already installed as %DRIVERNAME%
goto startgame
) else (
goto install_ac_driver
)

:install_ac_driver
sc.exe create %DRIVERNAME% type= kernel binPath="%CD%\%DRIVERFILE%"
echo AC installed as %DRIVERNAME%
goto startgame

:startgame
echo Launching %EXENAME%...
sc start "%DRIVERNAME%" >nul 2>&1
start /wait .\sp26\%EXENAME% hdeyguxs3zaumvlgvybm2vyc
sc stop "%DRIVERNAME%" >nul 2>&1
sc.exe delete %DRIVERNAME%

timeout 1
exit